cacheValue -- cache values of functions in their arguments

Synopsis

Usage:

((cacheValue KEY) f) x
Inputs:
- KEY
- f, a function
- x, an argument for f that has a cache table stored in it under x.cache
Outputs:
- f x is returned, but the value is saved in x.cache#KEY and not recomputed later. However, if the value found in x.cache#KEY is an a cache function, such as is returned by (stashValue KEY) f, then the value of x.cache#KEY x is returned instead, after first removing x.cache#KEY from x.cache.

Description

i1 : x = new HashTable from { val => 1000, cache => new CacheTable }

o1 = HashTable{cache => CacheTable{}}
               val => 1000

o1 : HashTable

i2 : f = (t -> (print "hi there"; t.val^4))

o2 = f

o2 : FunctionClosure

i3 : h = (cacheValue VALUE) f

o3 = -*a cache function*-

o3 : CacheFunction

i4 : h x
hi there

o4 = 1000000000000

i5 : h x

o5 = 1000000000000

i6 : peek'_2 x

o6 = HashTable{cache => CacheTable{VALUE => 1000000000000}}
               val => 1000

Code

../../m2/methods.m2:592:18-601:26: --source code:
cacheValue = key -> f -> new CacheFunction from (x -> (
          c := try x.cache else x.cache = new CacheTable;
          if c#?key then (
               val := c#key;
               if class val === CacheFunction then (
                    remove(c,key);
                    c#key = val x)
               else val
               )
          else c#key = f x))

For the programmer

The object cacheValue is a function closure.

cacheValue -- cache values of functions in their arguments

Synopsis

Description

Code

See also

For the programmer