mingens(GroebnerBasis) -- (partially constructed) minimal generator matrix

Synopsis

• Function: mingens

• Usage:

  mingens G

• Inputs:
  • G, a Gröbner basis
• Optional inputs:
  • Strategy => ..., default value null, a Strategy option value
• Outputs:
  • a matrix, whose columns form a (partially computed) minimal generating set

Description

If the Gröbner basis is only partially constructed, the returned result will be a partial answer. In the graded case this set can be extended to a minimal set of generators for the ideal or module.

i1 : R = QQ[a..f]

o1 = R

o1 : PolynomialRing

i2 : M = genericSymmetricMatrix(R,a,3)

o2 = | a b c |
     | b d e |
     | c e f |

             3       3
o2 : Matrix R  <--- R

i3 : I = minors(2,M)

               2                                                  2                                                  2
o3 = ideal (- b  + a*d, - b*c + a*e, - c*d + b*e, - b*c + a*e, - c  + a*f, - c*e + b*f, - c*d + b*e, - c*e + b*f, - e  + d*f)

o3 : Ideal of R

i4 : G = gb(I, PairLimit=>5)

o4 = GroebnerBasis[status: PairLimit; all S-pairs handled up to degree 1]

o4 : GroebnerBasis

i5 : mingens G

o5 = | e2-df ce-bf cd-be |

             1       3
o5 : Matrix R  <--- R

i6 : mingens I

o6 = | e2-df ce-bf cd-be c2-af bc-ae b2-ad |

             1       6
o6 : Matrix R  <--- R

See also

• GroebnerBasis -- the class of all Gröbner bases
• gb -- compute a Gröbner basis
• genericSymmetricMatrix -- make a generic symmetric matrix
• minors -- ideal generated by minors