degreeOfMap -- computes the degree of a rational map

Synopsis

Usage:

degreeOfMap(I)
Inputs:
- I, an ideal, an ideal defining the map
Optional inputs:
- Strategy => ..., default value Hm1Rees0Strategy, Choose a strategy for computing the degree of map
Outputs:
- an integer, the degree of the corresponding rational map

Description

Let $R$ be the polynomial ring $R=k[x_0,...,x_r]$ and $I$ be the homogeneous ideal $I=(f_0,f_1,...,f_s)$ where $deg(f_i)=d$. We compute the degree of the rational map $\mathbb{F}: \mathbb{P}^r \to \mathbb{P}^s$ defined by $$ (x_0: ... :x_r) \to (f_0(x_0,...,x_r), f_1(x_0,...,x_r), ..... , f_s(x_0,...,x_r)). $$ The degree can be computed by two different strategies and the default one is "Hm1Rees0Strategy".

The following example is a rational map without base points:

i1 : R = QQ[x,y,z]

o1 = R

o1 : PolynomialRing

i2 : I = ideal(random(4, R), random(4, R), random(4, R));

o2 : Ideal of R

i3 : betti res I

            0 1 2 3
o3 = total: 1 3 3 1
         0: 1 . . .
         1: . . . .
         2: . . . .
         3: . 3 . .
         4: . . . .
         5: . . . .
         6: . . 3 .
         7: . . . .
         8: . . . .
         9: . . . 1

o3 : BettiTally

i4 : degreeOfMap I

o4 = 16

In the following examples we play with the relations of the Hilbert-Burch presentation and the degree of $\mathbb{F}$ (see Proposition 5.2 and Theorem 5.12):

i5 : A = matrix{ {x, x^2 + y^2},
                 {-y, y^2 + z*x},
                 {0, x^2}
               };

             3       2
o5 : Matrix R  <--- R

i6 : I = minors(2, A) -- a birational map

             2       2    3    2    3    2
o6 = ideal (x y + x*y  + y  + x z, x , -x y)

o6 : Ideal of R

i7 : degreeOfMap I

o7 = 1

i8 : A = matrix{ {x^2, x^2 + y^2},
                 {-y^2, y^2 + z*x},
                 {0, x^2}
               };

             3       2
o8 : Matrix R  <--- R

i9 : I = minors(2, A) -- a non birational map

              2 2    4    3    4    2 2
o9 = ideal (2x y  + y  + x z, x , -x y )

o9 : Ideal of R

i10 : degreeOfMap I

o10 = 2

i11 : A = matrix{ {x^3, x^2 + y^2},
                  {-y^3, y^2 + z*x},
                  {0, x^2}
                };

              3       2
o11 : Matrix R  <--- R

i12 : I = minors(2, A) -- a non birational map

              3 2    2 3    5    4    5    2 3
o12 = ideal (x y  + x y  + y  + x z, x , -x y )

o12 : Ideal of R

i13 : degreeOfMap I

o13 = 3

i14 : A = matrix{ {x^3, x^4},
                  {-y^3, y^4},
                  {z^3, x^4}
                };

              3       2
o14 : Matrix R  <--- R

i15 : I = minors(2, A) -- a non birational map

              4 3    3 4   7    4 3     4 3    4 3
o15 = ideal (x y  + x y , x  - x z , - x y  - y z )

o15 : Ideal of R

i16 : degreeOfMap I

o16 = 12

The following examples are computed with the strategy "SatSpecialFibStrategy".

i17 : R = QQ[x,y,z,v,w]

o17 = R

o17 : PolynomialRing

i18 : I = ideal(random(1, R), random(1, R), random(1, R), random(1, R), random(1, R));

o18 : Ideal of R

i19 : degreeOfMap(I, Strategy=>SatSpecialFibStrategy)

o19 = 1

i20 : I = ideal(29*x^3 + 55*x*y*z, 7*y^3, 14*z^3, 17*v^3, 12*w^3)

                3              3     3     3     3
o20 = ideal (29x  + 55x*y*z, 7y , 14z , 17v , 12w )

o20 : Ideal of R

i21 : degreeOfMap(I, Strategy=>SatSpecialFibStrategy)

o21 = 81

Caveat

To call the method "degreeOfMap(I)", the ideal $I$ should be in a single graded polynomial ring.

Ways to use `degreeOfMap` :

"degreeOfMap(Ideal)"

For the programmer