next | previous | forward | backward | up | top | index | toc | Macaulay2 website
NormalToricVarieties :: OO ToricDivisor

OO ToricDivisor -- make the associated rank-one reflexive sheaf

Synopsis

Description

For a Weil divisor $D$ on a normal variety $X$ the associated sheaf ${\cal O}_X(D)$ is defined by $H^0(U, {\cal O}_X(D)) = \{ f \in {\mathbb C}(X)^* | (div(f)+D)|_U \geq 0 \} \cup \{0\}$. The sheaf associated to a Weil divisor is reflexive; it is equal to its bidual. A divisor is Cartier if and only if the associated sheaf is a line bundle

The first examples show that the associated sheaves are reflexive.

i1 : PP3 = toricProjectiveSpace 3;
 
i2 : K = toricDivisor PP3

o2 = - PP3  - PP3  - PP3  - PP3
          0      1      2      3

o2 : ToricDivisor on PP3
 
i3 : omega = OO K

          1
o3 = OO    (-4)
       PP3

o3 : coherent sheaf on PP3
 
i4 : omegaVee = prune sheafHom (omega, OO_PP3)

          1
o4 = OO    (4)
       PP3

o4 : coherent sheaf on PP3
 
i5 : omega === prune sheafHom (omegaVee, OO_PP3)

o5 = true
 
i6 : X = hirzebruchSurface 2;
 
i7 : D = X_0 + X_1

o7 = X  + X
      0    1

o7 : ToricDivisor on X
 
i8 : L = OO D

        1
o8 = OO   (-1, 1)
       X

o8 : coherent sheaf on X
 
i9 : LVee = prune sheafHom (L, OO_X)

        1
o9 = OO   (1, -1)
       X

o9 : coherent sheaf on X
 
i10 : L === prune sheafHom (LVee, OO_X)

o10 = true
 
i11 : rayList = {{1,0,0},{0,1,0},{0,0,1},{0,-1,-1},{-1,0,-1},{-2,-1,0}};
 
i12 : coneList = {{0,1,2},{0,1,3},{1,3,4},{1,2,4},{2,4,5},{0,2,5},{0,3,5},{3,4,5}};
 
i13 : Y = normalToricVariety(rayList,coneList);
 
i14 : isSmooth Y

o14 = false
 
i15 : isProjective Y

o15 = false
 
i16 : E = Y_0 + Y_2 + Y_4

o16 = Y  + Y  + Y
       0    2    4

o16 : ToricDivisor on Y
 
i17 : isCartier E

o17 = false
 
i18 : F = OO E

         1
o18 = OO   (1, 3, 2)
        Y

o18 : coherent sheaf on Y
 
i19 : FVee = prune sheafHom(F, OO_Y)

         1
o19 = OO   (-1, -3, -2)
        Y

o19 : coherent sheaf on Y
 
i20 : F === prune sheafHom(FVee, OO_Y)

o20 = true

Two Weil divisors $D$ and $E$ are linearly equivalent if $D = E + div(f)$, for some $f \in {\mathbb C}(X)^*$. Linearly equivalent divisors produce isomorphic sheaves.

i21 : PP3 = toricProjectiveSpace 3;
 
i22 : D1 = PP3_0

o22 = PP3
         0

o22 : ToricDivisor on PP3
 
i23 : E1 = PP3_1

o23 = PP3
         1

o23 : ToricDivisor on PP3
 
i24 : OO D1 === OO E1

o24 = true
 
i25 : X = hirzebruchSurface 2;
 
i26 : D2 = X_2 + X_3

o26 = X  + X
       2    3

o26 : ToricDivisor on X
 
i27 : E2 = 3*X_0 + X_1

o27 = 3*X  + X
         0    1

o27 : ToricDivisor on X
 
i28 : OO D2 === OO E2

o28 = true

See also