abstractVarietyMap -- make an abstract variety morphism

Synopsis

• Usage:

  f = abstractVarietyMap(Y,X,fUpper,fLower)

• Inputs:
  • Y, an abstract variety, the target of $f$
  • X, an abstract variety, the source of $f$
  • fUpper, the method for pulling back from $Y$ to $X$; if given as a ring map, this should be a ring map from the intersection ring of $Y$ to that of $X$. If given as a MethodFunction, there must be a method installed for pulling back elements of the intersection ring of $Y$ to that of $X$. Optionally, a method can also be given for pulling back sheaves from $Y$ to $X$, in which case the DefaultPullBack => false option must be set to override the default behavior.
  • fLower, the method from pushing forward from $X$ to $Y$. Must have a method installed for pushing forward elements of the intersection ring of $X$ to that of $Y$. Optionally, a method can also be given for pushing forward sheaves from $X$ to $Y$, in which case the DefaultPushForward => false option must be set to override the default behavior.
• Optional inputs:
  • DefaultPullBack => a Boolean value, default value true, if true, sheaf pullbacks are computed in the default manner from ring element pullbacks
  • DefaultPushForward => a Boolean value, default value true, if true, sheaf pushforwards are computed (if possible) in the default manner from ring element pushforwards
  • TangentBundle => an abstract sheaf, default value null, the relative tangent bundle of $f$. If not supplied, is computed anyway if possible.
  • SectionClass => a ring element, default value null, the class of a section of $f$, an element of the intersection ring of $X$
• Outputs:
  • f, an abstract variety map, the resulting map from $X$ to $Y$
• Consequences:

  • If fUpper is given as a ring map, then a new method is created for the pullback, encapsulating this ring map. However, if fUpper is given as a MethodFunction, then this MethodFunction is used directly, and may have new methods installed on it.
  • If the DefaultPullBack => true option is set (this is the default setting), then a method for pulling back sheaves is installed in the method fUpper. The default behavior is to pull back both Chern classes and Chern characters via the supplied map.
  • If the DefaultPullBack => true option is set (this is the default setting), and if the calculation of sheaf pushforward is possible (i.e. either $X$ and $Y$ have supplied tangent bundles and $fUpper$ can pull back sheaves, or the TangentBundle option is set), method for pulling back sheaves is installed in the method fUpper. The default behavior is to compute the pushforward of sheaves via Grothendieck-Riemann-Roch.

Description

i1 : X = point

o1 = point

o1 : an abstract variety of dimension 0

i2 : RX = intersectionRing X

o2 = RX

o2 : PolynomialRing

i3 : Y = abstractProjectiveSpace 3

o3 = Y

o3 : a flag bundle with subquotient ranks {1, 3}

i4 : RY = intersectionRing Y

o4 = RY

o4 : QuotientRing

i5 : fUpper = map(RX, RY, splice{4:0_RX})

o5 = map(RX,RY,{0, 0, 0, 0})

o5 : RingMap RX <--- RY

i6 : fLower = method()

o6 = fLower

o6 : MethodFunction

i7 : fLower RX := a -> promote(a,RY) * ctop last bundles Y;

i8 : incl = abstractVarietyMap(Y,X,fUpper,fLower)

o8 = incl

o8 : a map to Y from point

i9 : integral incl_* 1_RX

o9 = 1

i10 : X = point

o10 = point

o10 : an abstract variety of dimension 0

i11 : Y = abstractProjectiveSpace 3

o11 = Y

o11 : a flag bundle with subquotient ranks {1, 3}

i12 : incl = map(Y,X,OO_X)

o12 = incl

o12 : a map to Y from point